Wikidata:GLAM/Baden-Württemberg GLAM goes OpenData/Queries
Home | Objects | List of Collectors | List of Institutions and Places | Queries | Image Upload | Sources |
Anleitungen für Abfragen[edit]
Interface zum Bau von Visualisierungen[edit]
https://dataviz.toolforge.org/
Abfragen über existierende WikiProjekte[edit]
Scholia[edit]
Objekte oder Themen kontextualisieren, hier am Beispiel des Radfächers https://scholia.toolforge.org/topic/Q123059170 Die Abfrage kann durch den Austausch der Qid in der URL angepasst werden.
Wikidocumentaries[edit]
Visuell ansprechende Zusammenführung aller Daten, die zu einem Thema auf Wikidata, Wikipedia, Wikicommons zur Verfügung stehen. Hier am Beispiel der Kunstkammer https://wikidocumentaries-demo.wmcloud.org/Q122812575?language=de Die Abfrage kann durch den Austausch der Qid in der URL angepasst werden.
Wikidata tempo-spatial display[edit]
Zusammenstellung einer Zeitleiste aller Daten zu einem Objekt oder einer Sammlung. Hier am Beispiel der Kunstkammer https://wikidata-todo.toolforge.org/tempo_spatial_display.html?q=Q122812575&title=GLAM-BW
GLAM-BW-Project allgemein[edit]
"Objekte" des GLAM-BW-Project (focus list) mit deWikipedia-Artikel[edit]
#title:"Objekte" des GLAM-BW-Projects mit (de)-Wikipedia-Artikel
SELECT DISTINCT ?item ?itemLabel ?wpPage WHERE {
?item wdt:P5008 wd:Q122901643;
(wdt:P31/(wdt:P279+)) wd:Q386724.
OPTIONAL { ?item wdt:P18 ?image. }
?wpPage schema:about ?item;
schema:isPartOf <https://de.wikipedia.org/>
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Darstellung eines Einzelobjektes[edit]
Basierend auf der Abfrage "the topic in context" des Scholia-Projektes kann eine Visualisierung eines Einzelobjektes mit seinen Bezügen aufgrund der angegebenen Statements realisiert werden:
# tool: scholia
PREFIX target: <http://www.wikidata.org/entity/Q123059171>
#defaultView:Graph
SELECT ?node ?nodeLabel ?nodeImage ?childNode ?childNodeLabel ?childNodeImage ?rgb
WITH {
SELECT DISTINCT ?property WHERE {
?property a wikibase:Property;
wdt:P31 wd:Q18610173 ;
wdt:P31 wd:Q26940804 .
}
} AS %properties
WITH {
SELECT DISTINCT ?node ?childNode WHERE {
BIND(target: AS ?node)
?node ?p ?i.
?childNode ?x ?p.
?childNode rdf:type wikibase:Property.
FILTER(STRSTARTS(STR(?i), "http://www.wikidata.org/entity/Q"))
FILTER(STRSTARTS(STR(?childNode), "http://www.wikidata.org/entity/P"))
}
LIMIT 5000
} AS %nodes
WITH {
SELECT DISTINCT ?childNode ?node ?rgb WHERE {
BIND("EFFBD8" AS ?rgb)
target: ?p ?childNode.
?node ?x ?p.
?node rdf:type wikibase:Property.
FILTER(STRSTARTS(STR(?childNode), "http://www.wikidata.org/entity/Q"))
}
LIMIT 5000
} AS %childNodes
WHERE {
{
INCLUDE %nodes
}
UNION
{
INCLUDE %childNodes
}
OPTIONAL {
INCLUDE %properties
?property wikibase:directClaim ?nodeclaim.
?node ?nodeclaim ?nodeImage.
}
OPTIONAL {
INCLUDE %properties
?property wikibase:directClaim ?childNodeclaim.
?childNode ?childNodeclaim ?childNodeImage.
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Bilder[edit]
Bildergalerie aller hochgeladenen Objekte[edit]
#title:Bildergalerie
#defaultView:ImageGrid
SELECT ?item ?itemLabel ?image WHERE {
?item wdt:P5008 wd:Q122901643.
OPTIONAL { ?item wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Eigentumsverhältnisse / Sammler*innen[edit]
Abfrage von Eigentümer*innen von Objekten[edit]
#title:Eigentumsgraph von Objekten aus dem GLAM-BW-Projekt
#defaultView:Graph
SELECT ?owner ?ownerLabel ?ownerImage ?item ?itemLabel ?image ?edgeLabel ?rgb WHERE {
?item wdt:P5008 wd:Q122901643;
wdt:P127 ?owner;
wdt:P18 ?image.
OPTIONAL { ?owner wdt:P18 ?ownerImage. }
BIND("besitzt" AS ?edgeLabel)
BIND("cbcbcb" AS ?rgb)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Timeline(s)[edit]
Abfrage des Alters der Münzen dargestellt auf einem Zeitstrahl mit Bild avers[edit]
#title:Zeitstrahl des Münzenalters mit Bild der aversen Seite
#defaultView:Timeline
SELECT ?item ?itemLabel ?inceptionDate ?image WHERE {
?item wdt:P195 wd:Q123419474; wdt:P571 ?inceptionDate.
OPTIONAL { ?item p:P18 ?imageStmt. ?imageStmt ps:P18 ?image; pq:P518 wd:Q257418 }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Zeitstrahl der Eigentumsverhältnisse der Neuenstädter Sammlung[edit]
#title:Zeitstrahl der EigentümerInnen der Neuenstädter Sammlung
#defaultView:Timeline{"hide":["?startTime","?endTime"]}
SELECT ?owner ?ownerLabel ?startTime ?endTime (CONCAT(STR(YEAR(?startTime))," bis ", STR(YEAR(?endTime))) AS ?zeitraum) ?ownerImage WHERE {
wd:Q123419474 p:P127 ?ownerStmt.
?ownerStmt ps:P127 ?owner.
OPTIONAL { ?ownerStmt pq:P580 ?startTime. }
OPTIONAL { ?ownerStmt pq:P582 ?endTime. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
OPTIONAL { ?owner wdt:P18 ?ownerImage. }
}
Zeitstrahl Eigentümer Objekte[edit]
#title:Zeitstrahl der EigentümerInnen des Radfächers
#defaultView:Timeline{"hide":["?startTime","?endTime"]}
SELECT ?owner ?ownerLabel ?startTime ?endTime (CONCAT(STR(YEAR(?startTime))," bis ", STR(YEAR(?endTime))) AS ?zeitraum) ?ownerImage WHERE {
wd:Q123059170 p:P127 ?ownerStmt.
?ownerStmt ps:P127 ?owner.
OPTIONAL { ?ownerStmt pq:P1319 ?startTime. }
OPTIONAL { ?ownerStmt pq:P1326 ?endTime. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
OPTIONAL { ?owner wdt:P18 ?ownerImage. }
}
Kartenansicht[edit]
Ansicht der Herstellungsorte[edit]
#title:Karte der Herstellungsorte
#defaultView:Map{"hide":["?coords"]}
SELECT ?item ?itemLabel ?image ?Herstellungsort ?HerstellungsortLabel ?coords WHERE {
?item wdt:P5008 wd:Q122901643;
#?item wdt:P195 wd:Q122812575;
wdt:P1071 ?Herstellungsort.
?Herstellungsort wdt:P625 ?coords.
OPTIONAL { ?item wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Karte der Herstellungsorte mit Layer "Objekttyp"[edit]
#title:Karte der Herstellungsorte mit Layer der Objektart
#defaultView:Map
SELECT ?item ?itemLabel ?image ?Herstellungsort ?HerstellungsortLabel ?coords ?layer ?layerLabel WHERE {
?item wdt:P5008 wd:Q122901643;
#?item wdt:P195 wd:Q122812575;
wdt:P1071 ?Herstellungsort;
wdt:P31 ?layer.
?Herstellungsort wdt:P625 ?coords.
OPTIONAL { ?item wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Münzen[edit]
Bildergalerie der Münzen mit Depicts-Statement und Seitenangabe (revers...) über Qualifier "applies to part" gematched[edit]
#title: Abfragen der Motive je Münzseite mit dem zugehörigen Bild
#defaultView:ImageGrid
SELECT ?image ?coin ?coinLabel ?coinPart ?coinPartLabel ?depicts ?depictsLabel WHERE {
?coin wdt:P31 wd:Q41207;
wdt:P5008 wd:Q122901643;
p:P180 ?depictsStmt;
p:P18 ?imageStmt.
?depictsStmt ps:P180 ?depicts;
pq:P518 ?coinPart.
?imageStmt ps:P18 ?image; pq:P518 ?coinPart.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Wartungslisten[edit]
#title:Objekte des GLAM BW-Projekts mit "described by URL (P973)" ohne Qualifier "Sprache P973"
SELECT * WHERE {
?item wdt:P5008 wd:Q122901643;
p:P973 ?descrUrlStmt.
?descrUrlStmt ps:P973 ?descUrl.
FILTER(NOT EXISTS { ?descrUrlStmt pq:P407 ?language. })
}